Gecko [ corporacionhdm.com.pe ]

Name	Size	Permission	Date
autoconf.m4	3.61 KB	-rw-r--r--	2024-08-13 19:30
autoconf.m4f	473.79 KB	-rw-r--r--	2024-08-13 19:30
autoheader.m4	2.68 KB	-rw-r--r--	2024-08-13 19:30
autoscan.m4	1.98 KB	-rw-r--r--	2024-08-13 19:30
autotest.m4	2.84 KB	-rw-r--r--	2024-08-13 19:30
autoupdate.m4	4.22 KB	-rw-r--r--	2024-08-13 19:30
c.m4	59.55 KB	-rw-r--r--	2024-08-13 19:30
erlang.m4	9.68 KB	-rw-r--r--	2024-08-13 19:30
fortran.m4	63.72 KB	-rw-r--r--	2024-08-13 19:30
functions.m4	62.1 KB	-rw-r--r--	2024-08-13 19:30
general.m4	99.97 KB	-rw-r--r--	2024-08-13 19:30
go.m4	4.53 KB	-rw-r--r--	2024-08-13 19:30
headers.m4	29.8 KB	-rw-r--r--	2024-08-13 19:30
lang.m4	23.29 KB	-rw-r--r--	2024-08-13 19:30
libs.m4	15.84 KB	-rw-r--r--	2024-08-13 19:30
oldnames.m4	3.78 KB	-rw-r--r--	2024-08-13 19:30
programs.m4	28.93 KB	-rw-r--r--	2024-08-13 19:30
specific.m4	14.04 KB	-rw-r--r--	2024-08-13 19:30
status.m4	54.47 KB	-rw-r--r--	2024-08-13 19:30
types.m4	35.34 KB	-rw-r--r--	2024-08-13 19:30

Rename

# This file is part of Autoconf.                       -*- Autoconf -*-
# Interface with autoheader.

# Copyright (C) 1992-1996, 1998-2002, 2008-2012 Free Software
# Foundation, Inc.

# This file is part of Autoconf.  This program is free
# software; you can redistribute it and/or modify it under the
# terms of the GNU General Public License as published by the
# Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# Under Section 7 of GPL version 3, you are granted additional
# permissions described in the Autoconf Configure Script Exception,
# version 3.0, as published by the Free Software Foundation.
#
# You should have received a copy of the GNU General Public License
# and a copy of the Autoconf Configure Script Exception along with
# this program; see the files COPYINGv3 and COPYING.EXCEPTION
# respectively.  If not, see <http://www.gnu.org/licenses/>.

# Written by David MacKenzie, with help from
# Franc,ois Pinard, Karl Berry, Richard Pixley, Ian Lance Taylor,
# Roland McGrath, Noah Friedman, david d zuhn, and many others.

# AH_OUTPUT(KEY, TEXT)
# --------------------
# Pass TEXT to autoheader.
# This macro is `read' only via `autoconf --trace', it outputs nothing.
m4_define([AH_OUTPUT], [])

# AH_VERBATIM(KEY, TEMPLATE)
# --------------------------
# If KEY is direct (i.e., no indirection such as in KEY=$my_func which
# may occur if there is AC_CHECK_FUNCS($my_func)), issue an autoheader
# TEMPLATE associated to the KEY.  Otherwise, do nothing.  TEMPLATE is
# output as is, with no formatting.
#
# Quote for Perl '' strings, which are those used by Autoheader.
m4_define([AH_VERBATIM],
[AS_LITERAL_WORD_IF([$1],
	       [AH_OUTPUT(_m4_expand([$1]), AS_ESCAPE([[$2]], [\']))])])

# AH_TEMPLATE(KEY, DESCRIPTION)
# -----------------------------
# Issue an autoheader template for KEY, i.e., a comment composed of
# DESCRIPTION (properly wrapped), and then #undef KEY.
m4_define([AH_TEMPLATE],
[AH_VERBATIM([$1],
	     m4_text_wrap([$2 */], [   ], [/* ])[
@%:@undef ]_m4_expand([$1]))])

# AH_TOP(TEXT)
# ------------
# Output TEXT at the top of `config.h.in'.
m4_define([AH_TOP],
[m4_define([_AH_COUNTER], m4_incr(_AH_COUNTER))dnl
AH_VERBATIM([0000]_AH_COUNTER, [$1])])

# AH_BOTTOM(TEXT)
# ---------------
# Output TEXT at the bottom of `config.h.in'.
m4_define([AH_BOTTOM],
[m4_define([_AH_COUNTER], m4_incr(_AH_COUNTER))dnl
AH_VERBATIM([zzzz]_AH_COUNTER, [$1])])

# Initialize.
m4_define([_AH_COUNTER], [0])